Extension des rapports avec le Document Inbound Barcode

Dans cette documentation, vous apprendrez comment étendre un rapport dans Business Central avec un Document Inbound Barcode. Le code-barres est généré et ajouté automatiquement lors de l'impression du rapport ou lors de la réservation ou de la conversion d'un document.

Méthodologie

Il existe deux approches pour y parvenir :

Rapports personnalisés :
Dans les rapports personnalisés, vous pouvez intégrer le code requis directement dans le rapport.
Rapports standard :
Pour les rapports standard, il est possible de créer une extension de rapport qui implémente le code correspondant.

Veuillez noter qu'il existe des différences entre les rapports Word et les rapports RDLC qui doivent être prises en compte lors de la mise en œuvre.

Exigences

Avant de commencer, assurez-vous que les prérequis suivants sont remplis :

CORE doit être référencé dans l'extension.
Document Central doit être référencé dans l'extension.
Document Inbound doit être référencé dans l'extension.
Document Central doit être correctement licencié.
Document Central et Document Inbound doivent être activés dans la configuration du module correspondant.

En savoir plus sur la création d'un rapport de mise en page Word dans Microsoft Business Central.

En savoir plus sur la création d'un rapport de mise en page RDLC dans Microsoft Business Central.

Configuration dans Document Central

Pour garantir le bon fonctionnement, les configurations suivantes doivent être effectuées pour le rapport créé/étendu dans Document Central :

Une série de numéros pour le code-barres doit être configurée dans le Mapping. Le mapping doit être basé sur la table du rapport.
Dans les paramètres du rapport, les points suivants doivent être pris en compte :
Un type de contenu de code-barres doit être défini.
L'impression du code-barres doit être activée.

Extension des rapports RDLC

Dans cette section, nous ajoutons un Document Inbound Barcode à un rapport de votre choix.
Créez un nouveau fichier .al dans Visual Studio Code ou ouvrez un fichier .al existant qui étend le rapport souhaité.

Ajoutez le code suivant dans le fichier ouvert :

AL
reportextension 5227509 "DMSDI_EXT Test" extends XXX
{
    dataset
    {
        add(Header)
        {
            column(Global_Barcode; GlobalBarcode)
            { }
        }
        modify(Header)
        {
            trigger OnAfterAfterGetRecord()
            var
                LocalSIMDIBarcodeMgt: Codeunit "SIM_DI Barcode Management";
                LocalCodeunitSIMDMSSI: Codeunit "SIM_DMS SI";
                LocalEnumSIMDITypeOfBarcodes: Enum "SIM_DI Type of Barcodes";
                LocalRRef: RecordRef;
                LocalBarcodeText: Text;
            begin
                if LocalCodeunitSIMDMSSI.GetPdfPrint() then
                    exit;

                LocalRRef.Get(Header.RecordId());
                LocalBarcodeText := LocalSIMDIBarcodeMgt.CreateBarcode(LocalRRef, Header."No.", '', XXX, false);
                GlobalBarcode := LocalSIMDIBarcodeMgt.CreateLabel(LocalBarcodeText, 250, 600, true, Format(LocalEnumSIMDITypeOfBarcodes::Code128), 'PNG');
            end;
        }
    }
    var
        GlobalBarcode: Text;
}

Info

Dans l'Enum "LocalEnumSIMDITypeOfBarcodes", tous les types de codes-barres pris en charge sont définis. Pour changer le type de code-barres, il vous suffit de sélectionner la valeur souhaitée dans cet Enum.

Remplacez "XXX" par l'ID du rapport que vous souhaitez étendre (par exemple, 1306 pour le document de vente).
Publiez l'extension.
Ouvrez les mises en page de rapport dans Business Central.
Recherchez la mise en page que vous souhaitez étendre et cliquez sur "Mettre à jour et télécharger la mise en page".
Ouvrez le fichier de mise en page téléchargé.
Ajoutez une image en sélectionnant "Insérer" -> "Image".
Positionnez l'image ajoutée à l'endroit souhaité où le code-barres doit apparaître.
Cliquez avec le bouton droit sur l'image et sélectionnez "Propriétés de l'image".
Apportez les ajustements suivants dans la boîte de dialogue "Propriétés de l'image" :
- Général :
  - Nom : Barcode
  - Source de l'image : Base de données
  - Utiliser le champ : =System.Convert.FromBase64String(Fields!Global_Barcode.Value)
  - Utiliser le type MIME : image/bmp
- Taille :
  - Affichage : Ajuster proportionnellement
- Visibilité :
  - Expression : =IsNothing(Fields!Global_Barcode.Value) OR (Globals!PageNumber>1)
Enregistrez le fichier .rdl modifié.
Revenez aux mises en page de rapport dans Business Central et ajoutez la mise en page modifiée :
- Sélectionnez "Nouveau" pour ajouter une nouvelle mise en page et téléchargez le fichier révisé.
- Alternativement, vous pouvez remplacer la mise en page existante par le fichier modifié.
Liez le rapport à la nouvelle mise en page créée.
Lorsque vous imprimez le rapport, le code-barres doit s'afficher correctement.

Extension des rapports Word

Dans cette section, nous ajoutons un Document Inbound Barcode à un rapport sélectionné.
Créez un nouveau fichier .al dans Visual Studio Code ou ouvrez un fichier .al existant qui étend le rapport souhaité.

Ajoutez le code suivant dans le fichier ouvert, ou utilisez alternativement votre propre champ Blob à la place du champ Blob de l'enregistrement "SIM_CORE Temp Table". Assurez-vous que le champ a soit le sous-type "Bitmap", soit aucun sous-type défini.

AL
reportextension 5227509 "DMSDI_EXT Test" extends XXX
{
    dataset
    {
        add(Header)
        {
            column(Global_Barcode; GlobalRecordSIMCORETempTable."Blob 1")
            { }
        }
        modify(Header)
        {
            trigger OnAfterAfterGetRecord()
            var
                LocalSIMDIBarcodeMgt: Codeunit "SIM_DI Barcode Management";
                LocalCodeunitBase64Convert: Codeunit "Base64 Convert";
                LocalCodeunitSIMDMSSI: Codeunit "SIM_DMS SI";
                LocalRecordRef: RecordRef;
                LocalEnumSIMDITypeOfBarcodes: Enum "SIM_DI Type of Barcodes";
                LocalOutStream: OutStream;
                LocalBarcodeText: Text;
                LocalBarcodeBase64Text: Text;
            begin
                if LocalCodeunitSIMDMSSI.GetPdfPrint() then
                    exit;

                LocalRecordRef.Get(Header.RecordId());
                LocalBarcodeText := LocalSIMDIBarcodeMgt.CreateBarcode(LocalRecordRef, Header."No.", '', XXX, false);
                LocalBarcodeBase64Text := LocalSIMDIBarcodeMgt.CreateLabel(LocalBarcodeText, 250, 600, true, Format(LocalEnumSIMDITypeOfBarcodes::Code128), 'PNG');
                GlobalRecordSIMCORETempTable."Blob 1".CreateOutStream(LocalOutStream);
                LocalCodeunitBase64Convert.FromBase64(LocalBarcodeBase64Text, LocalOutStream);
            end;
        }
    }
    var
        GlobalRecordSIMCORETempTable: Record "SIM_CORE Temp Table";
}

Info

Dans l'Enum "LocalEnumSIMDITypeOfBarcodes", tous les types de codes-barres pris en charge sont enregistrés. Pour ajuster le type de code-barres, il vous suffit de sélectionner la valeur souhaitée dans cet Enum.

Remplacez "XXX" par l'ID du rapport que vous souhaitez étendre (par exemple, 1306 pour le document de vente).
Publiez l'extension.
Ouvrez le fichier Word du rapport.
Dans le document Word, accédez à l'onglet "Développeur" et sélectionnez l'option "Volet de mappage XML".
1. Cliquez à droite sur "Global_Barcode".
2. Sélectionnez "Insérer un élément de contenu" puis "Image".
Positionnez l'image à l'endroit du document où le code-barres doit être affiché.
Enregistrez le fichier Word.
Revenez à Business Central et téléchargez le fichier Word en tant que mise en page.
Liez la mise en page modifiée au rapport correspondant.
Lors de l'impression de ce rapport, le code-barres sera désormais généré.