Saltar al contenido

Implementación de la Funcionalidad Multimail

La implementación de la funcionalidad Multimail dentro del Despacho de Documentos puede extenderse a páginas adicionales. A continuación se presenta un ejemplo de cómo integrar la función Multimail. Esta implementación en particular está adaptada para la página asociada al registro Sales Invoice Header. Tenga en cuenta las líneas resaltadas en el fragmento de código, estas líneas deben modificarse para que se correspondan con el registro específico.

AL
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
action(SIM_EDS_Multimail)
{
    Caption = 'Multimail';
    ToolTip = 'This button sends all marked entries via email. The entries will be sent in case an active dispatch profile is configured for the respective entries.';
    Ellipsis = true;
    Image = SendTo;
    ApplicationArea = All;

    trigger OnAction()
    var
        LocalRecordSIMEDSSetup: Record "SIM_EDS Setup";
        LocalRecordSalesInvoiceHeader: Record "Sales Invoice Header";
        TempLocalRecordSIMEDSRecord: Record "SIM_EDS Record" temporary;
        TempLocalRecordSIMEDSBusinessPartner: Record "SIM_EDS Business Partner" temporary;
        TempLocalRecordSIMEDSDynamicBP: Record "SIM_EDS Dynamic BP" temporary;
        LocalRecordSIMEDSMultimailPreview: Record "SIM_EDS Multimail Preview";
        LocalCodeunitSIMEDSMgt: Codeunit "SIM_EDS Mgt";
        LocalCodeunitSIMEDSQueueMgt: Codeunit "SIM_EDS Queue Mgt";
        LocalCodeunitSIMEDSSI: Codeunit "SIM_EDS SI";
        LocalCodeunitSIMEDSMailMgt: Codeunit "SIM_EDS Mail Mgt";
        LocalRecordRef: RecordRef;
        LocalDynamicBusinessMappingExistsBoolean: Boolean;
        LocalNotAllEntriesPossible: Boolean;
        LocalExtendedBusinessMappingExistsBoolean: Boolean;
        LocalEntryNoListOfInteger: List of [Integer];
    begin
        LocalRecordSIMEDSMultimailPreview.DeleteAll();
        LocalCodeunitSIMEDSSI.ClearListsForMultimail();

        CurrPage.SetSelectionFilter(LocalRecordSalesInvoiceHeader);
        if not LocalRecordSIMEDSSetup.Get() then exit;

        if LocalRecordSalesInvoiceHeader.FindSet() then
            repeat
                LocalRecordRef.GetTable(LocalRecordSalesInvoiceHeader);

                LocalCodeunitSIMEDSMgt.GetRecords(LocalRecordRef, TempLocalRecordSIMEDSRecord);

                LocalCodeunitSIMEDSMgt.GetRecordAssignedData(
                    LocalRecordRef,
                    true,
                    LocalDynamicBusinessMappingExistsBoolean,
                    LocalExtendedBusinessMappingExistsBoolean,
                    TempLocalRecordSIMEDSRecord,
                    TempLocalRecordSIMEDSBusinessPartner,
                    TempLocalRecordSIMEDSDynamicBP,
                    true);

                TempLocalRecordSIMEDSRecord.SetRange("Table No.", LocalRecordRef.Number());
                TempLocalRecordSIMEDSRecord.SetRange("Output Type", TempLocalRecordSIMEDSRecord."Output Type"::"Mail");
                if not TempLocalRecordSIMEDSRecord.IsEmpty then
                    LocalCodeunitSIMEDSQueueMgt.SendEDS(LocalRecordRef, true, false, '', false, false, true)
                else begin
                    LocalNotAllEntriesPossible := true;
                    LocalCodeunitSIMEDSSI.AddFailedMultimailRecordToList(LocalRecordSalesInvoiceHeader.RecordId);
                    LocalCodeunitSIMEDSSI.AddFailedMultimailEntryNoToList(0);
                end;
            until LocalRecordSalesInvoiceHeader.Next() = 0;

        LocalEntryNoListOfInteger := LocalCodeunitSIMEDSSI.GetEntryNoList();

        if LocalEntryNoListOfInteger.Count <> 0 then begin
            if LocalCodeunitSIMEDSMgt.CheckCreatedMultimailEntries(LocalEntryNoListOfInteger) then begin
                LocalCodeunitSIMEDSMailMgt.SetMultimailDocuments(true);
                LocalCodeunitSIMEDSMailMgt.CheckEmailFilled(LocalEntryNoListOfInteger);
                LocalCodeunitSIMEDSMgt.Multimail(LocalEntryNoListOfInteger);
            end;
            if LocalNotAllEntriesPossible and not LocalRecordSIMEDSSetup."Use Multimail Preview" then
                Message(GlobalSelectedEnrtiesMultimailNotPossibleLabelTxt);
        end else
            Message(GlobalMultimailNotPossibleLabelMsg);

        LocalCodeunitSIMEDSSI.ClearListsForMultimail();

        LocalRecordSIMEDSMultimailPreview.Reset();
        LocalRecordSIMEDSMultimailPreview.DeleteAll();
    end;
}