Zum Inhalt

Erstellung personalisierter Anruferkarten-Factboxes

Erstellen der Factbox

Diese Dokumentation erklärt, wie Sie eine benutzerdefinierte Factbox für die Phone Connect Caller Card erstellen und wie Sie diese mit den Caller Cards verknüpfen. Wir beginnen mit der Erstellung einer benutzerdefinierten Factbox, die in diesem Beispiel die Projekte anzeigt, die mit dem jeweiligen Kontakt oder Kunden verknüpft sind.

AL
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
page 00002 "SIM_CTI Meine Neue Factbox"
{
    ApplicationArea = All;
    Caption = 'Meine Neue Factbox';
    PageType = Cardpart;

    layout
    {
        area(content)
        {
            group(Allgemein)
            {
                Caption = 'Allgemein';
                field("ArtikelNr."; GlobalProjectAmountInteger)
                {
                    Caption = 'Projekte';
                    ToolTip = 'Hier sehen Sie die gefundenen Projekteinträge';

                    // Wird ausgelöst, wenn der Benutzer auf das Feld klickt (Drill-Down-Aktion)
                    trigger OnDrillDown()
                    var
                        LocalJobListPage: Page "Job List";
                    begin
                        // Nur markierte Datensätze in der Jobliste anzeigen
                        GlobalRecordJob.MarkedOnly;

                        // Die Ansicht der Jobliste auf die markierten Datensätze setzen
                        LocalJobListPage.SetTableView(GlobalRecordJob);

                        // Die Jobliste ausführen
                        LocalJobListPage.RunModal();
                        CalcEntries();
                        CurrPage.Update();
                    end;
                }
            }
        }
    }

    // Bestimmt die Beziehung zwischen einem Kontakt oder Kunden und setzt globale Variablen entsprechend
    procedure CheckRelation(ParamCode: Code[20]; ParamEnumSIMCTIBusinessMappingType: Enum "SIM_CTI Business Mapping Type")
    var
        LocalRecordContact: Record Contact;
        LocalRecordContactBusinessRelation: Record "Contact Business Relation";
    begin
        // Geschäftsbeziehungen auf die mit Kunden verknüpften beschränken
        LocalRecordContactBusinessRelation.SetRange("Link to Table", LocalRecordContactBusinessRelation."Link to Table"::Customer);

        // Logik basierend auf dem Mapping-Typ (Kontakt oder Kunde) behandeln
        case ParamEnumSIMCTIBusinessMappingType of
            ParamEnumSIMCTIBusinessMappingType::Contact:
                begin
                    // Den Kontaktdatensatz abrufen
                    LocalRecordContact.Get(ParamCode);

                    // Den globalen Kontaktcode abhängig davon setzen, ob der Kontakt Teil eines Unternehmens ist
                    if LocalRecordContact."Company No." <> '' then
                        GlobalContactCode := LocalRecordContact."Company No."
                    else
                        GlobalContactCode := ParamCode;

                    // Den zugehörigen Kunden für den Kontakt finden
                    LocalRecordContactBusinessRelation.SetRange("Contact No.", GlobalContactCode);
                    if LocalRecordContactBusinessRelation.FindFirst() then
                        GlobalCustomerCode := LocalRecordContactBusinessRelation."No.";
                end;

            ParamEnumSIMCTIBusinessMappingType::Customer:
                begin
                    // Wenn der Mapping-Typ Kunde ist, Kunden setzen und den zugehörigen Kontakt finden
                    GlobalCustomerCode := ParamCode;
                    LocalRecordContactBusinessRelation.SetRange("No.", ParamCode);
                    if LocalRecordContactBusinessRelation.FindFirst() then
                        GlobalContactCode := LocalRecordContactBusinessRelation."Contact No.";
                end;
        end;

        // Nach dem Setzen der globalen Variablen die Projekteinträge berechnen
        CalcEntries();
    end;

    // Berechnet die Anzahl der relevanten Job-/Projekteinträge
    procedure CalcEntries()
    var
        LocalRecordContact: Record Contact; // Lokale Variable zum Durchlaufen der Kontakte
    begin
        GlobalProjectAmountInteger := 0; // Projektzähler zurücksetzen

        if GlobalContactCode <> '' then begin
            // Kontakte basierend auf der gespeicherten Firmennummer filtern
            LocalRecordContact.SetRange("Company No.", GlobalContactCode);

            if LocalRecordContact.FindSet() then
                repeat
                    // Kundenfilter anwenden, falls gesetzt
                    if GlobalCustomerCode <> '' then
                        GlobalRecordJob.SetRange("Sell-to Customer No.", GlobalCustomerCode);

                    // Jobs nach Kontaktnummer filtern
                    GlobalRecordJob.SetRange("Sell-to Contact No.", LocalRecordContact."No.");

                    // Passende Projekteinträge markieren
                    if GlobalRecordJob.FindSet() then begin
                        GlobalRecordJob.Mark();
                        GlobalRecordJob.Reset(); // Filter für die nächste Schleifeniteration zurücksetzen
                    end;
                until LocalRecordContact.Next() = 0;
        end;

        // Filter zurücksetzen und erneut anwenden, um markierte Jobs zu zählen
        GlobalRecordJob.Reset();
        GlobalRecordJob.SetRange("Sell-to Customer No.", GlobalCustomerCode);
        GlobalRecordJob.MarkedOnly;

        // Die markierten Projekteinträge zählen
        GlobalProjectAmountInteger += GlobalRecordJob.Count;

        // Die Seite aktualisieren, um die Feldanzeige zu erneuern
        CurrPage.Update();
    end;

    var
        GlobalRecordJob: Record Job;                 // Enthält die Projekteinträge
        GlobalProjectAmountInteger: Integer;         // Speichert die Anzahl der gefundenen Jobs
        GlobalCustomerCode: Code[20];                // Speichert den Kundencode
        GlobalContactCode: Code[20];                 // Speichert den Kontaktcode
}

Der unten gezeigte Beispielcode demonstriert, wie die Beziehung zwischen dem Kontakt und dem Kunden identifiziert wird und wie die entsprechenden Daten sowohl für den Kontakt als auch für den Kunden anschließend angezeigt werden.

Hinzufügen der Factbox zur Caller Card

Nachdem Sie Ihre Factbox erstellt haben, muss sie mit der gewünschten Phone Connect Caller Card verknüpft werden. Dazu muss eine neue Page Extension der entsprechenden Caller Card erstellt werden.

Im unten gezeigten Beispiel wird die Caller Card "Call In Contact Sales" erweitert. Da es sich um eine Kontakt-Caller-Card handelt, wird der Enum-Wert entsprechend auf Kontakt gesetzt.

AL
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
pageextension 00001 "SIM_CTIDocu CTI" extends "SIM_CTI Call In Cont. - Sales"
{
    layout
    {
        addafter(SIM_CTISalesFB)
        {
            part(NewFactbox; "SIM_CTI Meine Neue Factbox")
            {
                ApplicationArea = all;
            }
        }
    }

    trigger OnAfterGetCurrRecord()
    var
        LocalEnumSIMCTIBusinessMappingType: Enum "SIM_CTI Business Mapping Type";
    begin
        CurrPage.NewFactbox.Page.CheckRelation(Rec."No.", LocalEnumSIMCTIBusinessMappingType::Contact);
    end;
}

Nachdem Sie Ihre benutzerdefinierte Factbox erstellt und mit der Caller Card verknüpft haben, ist die Einrichtung abgeschlossen. Ihre Factbox ist nun bereit für die nahtlose Nutzung.