Zum Inhalt

Senden der Datei über eine benutzerdefinierte Codeunit

In dieser Dokumentation erstellen wir eine Beispiel-Codeunit, die die Integration von externem Code ermöglicht und es Document Dispatch ermöglicht, Dateien zu senden, die über eine Codeunit empfangen wurden.

Info

Diese benutzerdefinierte Codeunit muss in einer benutzerdefinierten Erweiterung implementiert werden. Bitte beachten Sie die Kommentare in der Beispiel-Codeunit.

Folgende Voraussetzungen müssen erfüllt sein: Die Document Dispatch-Erweiterung muss lizenziert werden. Auf die Erweiterung Document Dispatch muss in der benutzerdefinierten Erweiterung verwiesen werden. Document Dispatch Custom Codeunit:

AL
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
codeunit 50000 "Document Dispatch Custom Codeunit"
{
    TableNo = "SIM_EDS Record Attachment";
    Permissions = tabledata "SIM_EDS Queue Line" = RIM;
    trigger OnRun()
    begin
        CreateCustomAttatchments(Rec)
    end;

    var
        GlobalCodeunitSIMEDSSI: Codeunit "SIM_EDS SI";

    procedure CreateCustomAttatchments(ParamRecordSIMEDSRecordAttachment: Record "SIM_EDS Record Attachment")
    var
        LocalRecordSIMEDSQueueLine: Record "SIM_EDS Queue Line";
        LocalCodeunitBase64Convert: Codeunit "Base64 Convert";
        LocalCodeunitSIMCORERecordRef: Codeunit "SIM_CORE RecordRef";
        LocalCodeunitSIMCOREDataMapping: Codeunit "SIM_CORE Data Mapping";
        LocalCodeunitSIMCOREText: Codeunit "SIM_CORE Text";
        LocalRecordId: RecordId;
        LocalRRecordRef: RecordRef;
        LocalMappingRecordRef: RecordRef;
        LocalResultRecordRef: RecordRef;
        LocalOOutStream: OutStream;
        LocalFileBase64StringText: Text;
        LocalFilenameTempText: Text;
        LocalLineNoInteger: Integer;
        LocalDoExportBoolean: Boolean;

    begin
        // Prüfen, ob die Codeunit eingerichtet ist
        if GlobalCodeunitSIMEDSSI.GetCodeunitRecID() = '' then exit;
        if GlobalCodeunitSIMEDSSI.GetCodeunitQueueID() = 0 then exit;
        if not Evaluate(LocalRecordId, GlobalCodeunitSIMEDSSI.GetCodeunitRecID()) then exit;
        if not LocalRRecordRef.Get(LocalRecordId) then exit;

        // Get the Queue Line No. from the Document Dispatch SI codeunit
        LocalLineNoInteger := GlobalCodeunitSIMEDSSI.GetCodeunitQueueLineNo();

        // Abrufen der Datensatzreferenz aus dem Attachment Record
        if ParamRecordSIMEDSRecordAttachment."Dynamic Mapping Code" = '' then
            LocalCodeunitSIMCORERecordRef.FilterRecRefByKey(LocalRRecordRef, LocalResultRecordRef)
        else begin
            LocalCodeunitSIMCORERecordRef.FilterRecRefByKey(LocalRRecordRef, LocalMappingRecordRef);
            LocalCodeunitSIMCOREDataMapping.GetRecordFromMappingHeader(
                ParamRecordSIMEDSRecordAttachment."Dynamic Mapping Code",
                LocalMappingRecordRef,
                LocalResultRecordRef
            );
            LocalMappingRecordRef.Close();
        end;

        // Durch die Ergebnisdatensätze iterieren
        if LocalResultRecordRef.FindSet() then
            repeat
                LocalDoExportBoolean := false;

                // Logik zur Bestimmung, ob der Datensatz exportiert werden soll
                LocalDoExportBoolean := true;

                if LocalDoExportBoolean then begin
                    LocalLineNoInteger += 10000;
                    LocalRecordSIMEDSQueueLine.Init();
                    LocalRecordSIMEDSQueueLine."Queue Entry No." := GlobalCodeunitSIMEDSSI.GetCodeunitQueueID();
                    LocalRecordSIMEDSQueueLine."Line No." := LocalLineNoInteger;

                    LocalRecordSIMEDSQueueLine.Type := ParamRecordSIMEDSRecordAttachment.Type;
                    LocalRecordSIMEDSQueueLine."Attachment Group" := ParamRecordSIMEDSRecordAttachment."Attachment Group";
                    LocalRecordSIMEDSQueueLine."Record Attachment Line No." := ParamRecordSIMEDSRecordAttachment."Line No.";
                    LocalRecordSIMEDSQueueLine.Description := ParamRecordSIMEDSRecordAttachment.Description;
                    LocalRecordSIMEDSQueueLine."Source ID" := LocalResultRecordRef.RecordId;

                    LocalRecordSIMEDSQueueLine."Codeunit File Found" := true;
                    LocalRecordSIMEDSQueueLine."Optional Attachment" := ParamRecordSIMEDSRecordAttachment."Optional Attachment";
                    LocalRecordSIMEDSQueueLine."Attach Tag" := ParamRecordSIMEDSRecordAttachment."Default selection";

                    case ParamRecordSIMEDSRecordAttachment."Codeunit PDF Type" of
                        //PDF
                        ParamRecordSIMEDSRecordAttachment."Codeunit PDF Type"::PDF,
                        ParamRecordSIMEDSRecordAttachment."Codeunit PDF Type"::"PDF/A-3":
                            begin
                                LocalFilenameTempText := 'Test.pdf';
                                // Convert file to Base64 and write to queue line
                                LocalFileBase64StringText := 'BASE64STRING';
                            end;

                        // Word
                        ParamRecordSIMEDSRecordAttachment."Codeunit PDF Type"::"Word":
                            begin
                                LocalFilenameTempText := 'Test.docx';
                                LocalFileBase64StringText := 'BASE64STRING';
                            end;

                        //Excel
                        ParamRecordSIMEDSRecordAttachment."Codeunit PDF Type"::"Excel":
                            begin
                                LocalFilenameTempText := 'Test.xlsx';
                                LocalFileBase64StringText := 'BASE64STRING';
                            end;

                        //XML
                        ParamRecordSIMEDSRecordAttachment."Codeunit PDF Type"::"XML":
                            begin
                                LocalFilenameTempText := 'Test.xml';
                                LocalFileBase64StringText := 'BASE64STRING';
                            end;
                    end;

                    LocalRecordSIMEDSQueueLine."Document Name" := CopyStr(LocalFilenameTempText, 1, 250);
                    LocalRecordSIMEDSQueueLine."Filename Extension" := CopyStr(
                                LocalCodeunitSIMCOREText.GetFileExtension(LocalRecordSIMEDSQueueLine."Document Name"),
                                1,
                                MaxStrLen(LocalRecordSIMEDSQueueLine."Filename Extension")
                            );

                    Clear(LocalOOutStream);
                    LocalRecordSIMEDSQueueLine."Document Blob".CreateOutStream(LocalOOutStream);
                    LocalCodeunitBase64Convert.FromBase64(LocalFileBase64StringText, LocalOOutStream);

                    // Insert the queue line
                    LocalRecordSIMEDSQueueLine.Insert();
                end;
            until LocalResultRecordRef.Next() = 0;

        GlobalCodeunitSIMEDSSI.SetCodeunitQueueLineNo(LocalLineNoInteger);
    end;
}